Итак, необходимо для какого либо свойства строкового типа обеспечить возможность в Инспекторе объектов не только вводить значение с клавиатуры, но еще и выбрать одно из списочных значений.

Для этого необходимо унаследовать класс TStringProperty и перекрыть несколько методов.

Во-первых, необходимо перекрыть метод GetAttributes для того, чтобы оповестить инспектор объектов о том, каким образом допускается редактировать свойство.

Во-вторых, для формирования списка вариантов значений необходимо переопределить метод GetValues.

Таким образом, интерфейсная часть редактора свойства будет выглядеть следующим образом:

  TFormatAngleProperty=class(TStringProperty)
    public
    function GetAttributes: TPropertyAttributes; override;
    procedure GetValues(Proc: TGetStrProc); override;
   end;

Реализация метода-функции GetAttributes заключается в возврате определенных элементов множества типа TPropertyAttributes.

Многим элементам этого множества соответствуют методы редактора свойств.

Наиболее важные элементы множества и соответствующие им методы редактора свойств приведены в таблице.

Например, если необходимо, чтобы в инспекторе объектов появился список возможных значений и при выборе одного из них свойство обновилось в этот же момент, реализация метода GetAttributes может быть следующей.

function TFormatAngleProperty.GetAttributes: TPropertyAttributes;
begin
  Result:=[paValueList, paAutoUpdate];
end;

В соответствии с таблицей 1, если включен атрибут paValueList, то для формирования самих значений должен быть реализован метод GetValues.

Метод GetValues имеет один параметр процедурного типа, который вызывается для каждого помещаемого в список значения.

procedure TFormatAngleProperty.GetValues(Proc: TGetStrProc);
begin
  inherited;
  Proc('%d °');
  Proc('%d');
  Proc('a=%d');
  Proc('a=%d °');
end;

Результат работы редактора свойства приведен на рис.

Рис. 12.2. Рис. 2. Редактор свойства в действии

Для редактирования свойства Azimuth было бы удобно ввести значение с помощью самого компонента.

Для этого необходимо спроектировать диалог, содержащий аналогичный компонент и элементы управления для подтверждения выбора (например, кнопку).

Вариант диалога приведен на рис. 3.

Рис. 12.3. Рис. 3. Диалог редактирования свойства Azimuth

Для того, чтобы обеспечить изменение свойства с использованием диалога нужно в методе GetAttributes включить атрибут paDialog:

function TAzimuzhProperty.GetAttributes: TPropertyAttributes;
begin
 Result := [paDialog];
end;

Создание и вызов диалога редактирования производится в соответствующем атрибуту paDialog методе Edit:

procedure TAzimuzhProperty.Edit;
begin
  inherited;
  dlgAzimuth:=TdlgAzimuth.Create(Application);
  try
  dlgAzimuth.Caption:= Format('%s.%s.%s',[TComponent(GetComponent(0)).Owner.Name, TComponent(GetComponent(0)).Name ,GetName ]);
  dlgAzimuth.Compass1.Azimuth:=TAzimuth(GetOrdValue);
  if dlgAzimuth.ShowModal=mrOk then SetOrdValue(dlgAzimuth.Compass1.Azimuth);
  finally
  dlgAzimuth.Free;
  end;
end;

После создания диалога его заголовок устанавливается равным имени "хозяина" компонента, имени компонента и имени свойства, разделяемыми точками. Затем свойство Azimuth компонента на диалоге устанавливается равным значению редактируемого свойства.

Если диалог закрылся подтверждением, то с помощью метода SetOrdValue устанавливается значение редактируемого свойства.

Рис. 12.4. Рис. 4. Диалоговый редактор свойства в действии

Как это выглядит в действии можно увидеть здесь.