Когда компонент выбран, и пользователь нажимает правую кнопку мыши или сочетание клавиш <Alt+F10>, то редактор форм отображает контекстное меню. Для определения количества пунктов меню редактор форм вызывает метод GetVerbCount редактора компонента. Другими словами пользовательский редактор компонента перекрывает этот метод для возвращения количества пунктов, подлежащих добавлению в контекстное меню.

Interface
Uses …, DesignEditors, DesignIntf;
   TCompasEditor=class(TComponentEditor)
  public
    function GetVerbCount: Integer; override;
…
   end;

implementation
function TCompasEditor.GetVerbCount: Integer;
begin
  Result:=10;
end;

Если метод GetVerbCount возвращает число, превышающее ноль, то дизайнер формы вызывает метод GetVerb редактора компонента по одному разу для каждого пункта, подлежащего добавлению. Таким образом метод GetVerb будет вызван со параметром от 0 до GetVerbCount-1.

Метод GetVerb отвечает за указание строк, которые должны быть использованы для новых пунктов меню. Когда метод вызывается, он передает индексный параметр, указывающий на то, какой пункт меню должен быть добавлен. Этот метод перекрывается для возвращения Проектировщику форм строкового значения, которое основано на параметре.

function TCompasEditor.GetVerb(Index: Integer): string;
begin
  case Index of
  0: Result:='Compass Editor...';
  1: Result:='-';

  2: Result:='&N';
  3: Result:='NE';
  4: Result:='E';
  5: Result:='SE';
  6: Result:='S';
  7: Result:='SW';
  8: Result:='W';
  9: Result:='NW';
  end;
end;

Таким образом, после регистрации редактора компонентов верхняя (пользовательская) часть всплывающего меню будет выглядеть следующим образом:

Рис. 13.2.

function TCompasEditor.GetVerb(Index: Integer): string;
begin
  case Index of
  0: Result:='Compass Editor...';
  1: Result:='-';

  2: Result:='&N';
  3: Result:='NE';
  4: Result:='&E';
  5: Result:='SE';
  6: Result:='&S';
  7: Result:='SW';
  8: Result:='&W';
  9: Result:='NW';
  end;
end;

В этом случае меню выглядит вполне логично: основные стороны света снабжены горячими клавишами, а промежуточные – нет:

Рис. 13.3.

Когда пользователь выбирает один из вновь добавленных пунктов меню, вызывается метод ExecuteVerb редактора компонента. Этот метод получает в качестве своего единственного параметра индекс выбранного пункта меню. Следовательно, метод ExecuteVerb отвечает за осуществление соответствующего действия, исходя из выбранного пункта меню.

procedure TCompasEditor.ExecuteVerb(Index: Integer);
var
N, E, S, W: string;
begin
  inherited;
    case Index of
  0:
  begin
  dlgCompas:=TdlgCompas.Create(Application);
  try
  dlgCompas.Caption:= Format('%s.%s',[
  Component.Owner.Name, Component.Name ]);
  with dlgCompas, TCompass(Component)  do
  begin
  Compass1.Azimuth:=Azimuth;
  EditN.Text:=DirNames.N;
  EditE.Text:=DirNames.E;
  EditS.Text:=DirNames.S;
  EditW.Text:=DirNames.W;

  if dlgCompas.ShowModal=mrOk then
    begin
    TCompass(Component).Azimuth:=dlgCompas.Compass1.Azimuth;
    N:=system.copy(EditN.Text,1,1);
    E:=system.copy(EditE.Text,1,1);
    S:=system.copy(EditS.Text,1,1);
    W:=system.copy(EditW.Text,1,1);

    DirNames.N:=Char(N[1]);
    DirNames.E:=Char(E[1]);
    DirNames.S:=Char(S[1]);
    DirNames.W:=Char(W[1]);

    end;
  end;
  finally
  dlgCompas.Free;
  end;
  end;

    2..9: TCompass(Component).Azimuth:=45*(Index-2);
  end;
  Designer.Modified;
end;

Поскольку метод ExecuteVerb вызывается из каждого созданного пункта меню, то обычно он оформляется с использованием языковой конструкции case, с помощью которой определяется, какой именно фрагмент кода должен быть выполнен.

Так, в приведенном примере при вызове первого пункта меню (с индексом 0) создается и показывается диалог, на котором размещены элементы управления, необходимые для редактирования всех необходимых свойств.

Рис. 13.4.

Если диалог закрыть нажатием кнопки OK, то свойства редактируемого компонента принимают вновь введенные значения, а диалог – разрушается.

При вызове других пунктов меню значение азимута устанавливается кратным 45 градусам. Конкретное значение зависит от индекса пункта меню.

Какой бы пункт меню редактора компонента не был выбран, в завершении редактор форм, доступный через объект Designer вызовом метода Modified уведомляется о том, что компонент был модифицирован. Это заставляет редактор форм обновить значения свойств, отображаемых в инспекторе объектов и перерисовывает компонент.

Рис. 13.5.

Когда осуществляется двойной щелчок на компоненте, вызывается метод Edit редактора компонента. Этот метод обеспечивает еще один способ выполнения того же самого действия. Если метод Edit не перекрывается в порожденном классе, унаследованный метод класса TComponentEditor выполнит первое выражение, определенное в редакторе. Конечно, это происходит только в том случае, если метод GetVerbCount возвращает значение, превышающее нуль.

procedure TComponentEditor.Edit;
begin
  if GetVerbCount > 0 then ExecuteVerb(0);
end;