Класс TComponent обеспечивает свойства и методы, которые обеспечивают управление компонентами в дизайнере форм. Помимо свойств Name (Имя) и Tag (Дескрипотор), класса TComponent вводит еще несколько свойств, полезных для создания компонентов. Одним из наиболее полезных и, как следствие, часто используемых является свойство ComponentState, представляющее собой множество, определяющее состояние компонента.

Наиболее часто используемые элементы множества ComponentState приведены в Таблица 4.1.

Распространенное использование свойства ComponentState заключается в определении, находится ли компонент во время разработки. Например (внимание на экран), компонент TImage использует это свойство для того, чтобы узнать, нужно ли рисовать пунктирную линию вокруг элемента управления:

procedure TImage.Paint;
begin
  if csDesigning in ComponentState then
	with inherited Canvas do
	begin
	  Pen.Style := psDash;
	  Brush.Style := bsClear;
	  Rectangle(0, 0, Width, Height);
	end;
  ...
end;

Класс TComponent так же вводит два свойства, отвечающие за принадлежность компонента другим компонентам. Во-первых, это свойство Owner, определяющее компонент-владелец, а, во-вторых, это свойство Components, представляющее собой массив ссылок на дочерние компоненты.

Самым важным фактом, который обеспечивают эти два свойства, заключается в том, что за разрушение объекта ответственен владелец.

Переходя к методам TComponent следует, прежде всего, упомянуть метод Notification (дословно – «Уведомление»), вызывающийся каждый раз, когда компонент располагается на форме или удаляется с нее. Перекрытие метода Notification позволяет избежать ошибок, которые могли бы возникнуть в случае удаления свойств, являющихся ссылкой на компонент.

Например, метка, а точнее ее предок TCustomLabel в переопределенном методе Notification проверяет не удаляется ли компонент, на который она ссылается в своем поле FFocusControl. Если это так, то ссылка устанавливается в Nil, что позводяет избежать ошибки защиты памяти:

procedure TCustomLabel.Notification(AComponent: TComponent; Operation: TOperation);
begin
  inherited Notification(AComponent, Operation);
  if (Operation = opRemove) and (AComponent =
      FFocusControl) then FFocusControl := nil; 
end;

В TComponent определен еще один весьма полезный виртуальный метод Loaded, вызывающийся в тот момент, когда все значения компонента считаны из файла формы. Вызов Loaded происходит раньше, чем отображается форма и компонент, поэтому его обработка не связана с перерисовкой компонента.

Пример использования метода Loaded можно найти в компоненте TMediaPlayer:

procedure TMediaPlayer.Loaded;
begin
  inherited Loaded;
  if (not (csDesigning in ComponentState)) and FAutoOpen then
    Open;
end;

Суть переопределенного метода заключается в проверке считаны ли все свойства из файла формы и если да, то если компонент не находится в состоянии проектирования и установлено в свойство AutoOpen в True. Если эти два условия выполняются, то TMediaPlayer пытается открыть заданный файл.

Следующим в иерархии классов после TComponent идет родоначальник всех визуальных компонент TControl.

Класс TControl вводит ряд важных свойств, необходимых для визуальных компонентов. Это, прежде всего, свойство Parent, определяющее компонент, на поверхности которого находится текущий объект. По аналогии с Owner, ответственным за разрушение объекта, Parent в ответе за передачу сообщения на прорисовку объекта.

Второе представляющее интерес свойство – это свойство ControlStyle. Наиболее важные элементы множества ControlStyle приведены в таблице. Обычно множество ControlStyle изменяют в конструкторе Create для изменения поведения компонента.

Кроме того, в классе TControl объявлено множество методов диспетчеризации событий мыши.

Класс TGraphicControl является основой для создания графических элементов управления, не имеющего собственного идентификатора окна, но способного реагировать на события мыши. Пользовательская отрисовка происходит на свойстве Canvas в виртуальном методе Paint, переопределяемом в классе-наследнике.

Класс TWinControl используется в качестве базового для создания компонентов, инкапсулирующих существующие элементы управления, которые сами себя рисуют. Такие компоненты включают стандартные элементы управления Windows.

Класс TWinControl реализует свойство Handle, являющееся ссылкой на идентификатор окна базового элемента управления. Это значит, что наследники TWinControl могут обрабатывать события клавиатуры и изменения фокуса.

При создании наследников TWinControl в большинстве случаев требуется переопределять виртуальные методы CreateParams и CreateWnd. Метод CreateWnd вызывается при создании окна, при этом CreateWnd вызывает CreateParams для инициализации записи параметров создания окна и затем вызывает CreateWindowsHandle для создания реального идентификатора окна. Затем CreateWnd устанавливает размер окна и устанавливает шрифт элемента управления.

На практике это выглядит не так страшно, как звучит.

TSmartListBox = class(TListBox)
...
implementation

procedure TSmartListBox.CreateParams(var Params: TCreateParams);
begin
  inherited;
  Params.Style:=Params.Style or WS_HSCROLL;
end;

procedure TSmartListBox.CreateWnd;
begin
  inherited;
  Perform(LB_SETHORIZONTALEXTENT,2,0);
  ShowScrollBar(Handle,SB_HORZ,true)
end;

В приведенном примере создается элемент управления, наследуемый от TListBox. В методе CreateParams в стиль окна добавляется флаг WS_HSCROLL, определяющий наличие полосы горизонтальной прокрутки. В методе CreateWnd текущему объекту посылается сообщение LB_SETHORIZONTALEXTENT, заставляющее установить небольшой отступ в прокрутке и включается видимость полосы прокрутки.

В результате элемент управления получает горизонтальную полосу прокрутки.

В ряде случаев требуется элемент управления, обладающий идентификатором окна и в то же время позволяющий использовать Canvas для пользовательской отрисовки компонента. К счастью такой класс существует и называется он TCustomControl. Он является удачной комбинацией оконного класса TWinControl и графического элемента управления TGraphicControl.