Процесс создания заготовки нового компонента показан на рис. 2.1 и описан ниже.

Рис. 2.1. Cоздание нового компонента с помощью мастера New VCL Component

В появившемся окне мастера (см. Рисунок 1) нужно выбрать класс, от которого наследуется новый компонент.

Рис. 2.2. Рисунок 1

Нажмите кнопку Next>>.

В появившемся втором окне мастера (Рисунок 2) нужно ввести необходимые данные.

1. В поле Class Name (Имя класса) нужно ввести имя класса нового компонента.

Рис. 2.3. Рисунок 2

2. В поле Palette Page (Страница палитры компонентов) нужно ввести название палитры компонентов, на которой будет размещаться новый компонент. Его можно выбрать из выпадающего списка (который появиться после нажатия на рядом расположенной кнопке) или ввести имя новой страницы. Здесь допустимы любые символы, в том числе и из национальных алфавитов и пробелы.

3. В поле Unit Name (Имя модуля) нужно ввести имя модуля, который будет содержать объявление и реализацию нового класса.

Модулю следует давать имя созвучное с именем класса. Самый простой вариант – имя класса без первой буквы T.

В том случае, если модуль будет содержать более одного класса (а в реальных библиотеках так чаще всего и бывает), то модуль следует назвать каким-то общим именем.

4. Поле Search Path (Путь поиска) можно оставить без изменения. Он нужен для того, чтобы компилятор нашел все модули, расположенные в разных папках.

После того, как все данные будут введены, следует нажать кнопку Next>> и перейти к завершающему диалогу мастера (Рисунок 3).

Рис. 2.4. Рисунок 3

В конечном диалоге нечего изменять, а можно лишь согласиться с созданием модуля, нажав кнопку Finish.

Коечным результатом работы мастера является модуль на подобии приведенного ниже.

unit syPost;

interface

uses
  SysUtils, Classes, Controls;

type
  TsyPostZip = class(TGraphicControl)
  private
    { Private declarations }
  protected
    { Protected declarations }
  public
    { Public declarations }
  published
    { Published declarations }
  end;

procedure Register;

implementation

procedure Register;
begin
  RegisterComponents('Юшинин', [TsyPostZip]);
end;

end.

Из приведенного листинга видно, что в интерфейсном разделе (interface) модуль содержит объявление класса, при этом в разделе uses упомянут модуль, в котором реализован класс-предок. В данном случае это – модуль Controls.

Так же в интерфейсной части размещено объявление в реализационной части (implementation) процедуры Register, отвечающей за регистрацию компонента.

Как видно из кода модуля, пока новый класс ничем не отличается от своего предка. Однако для того, чтобы продолжить над ним работы необходимо создать тестовое приложение для испытания нового компонента.

Создается тестовое приложение, как простой проект c помощью пункта меню New/ VCL Forms Application – Delphi for Win32.

Проект следует сохранить под «осмысленным» именем, чтобы в дальнейшем было понятно, для чего он предназначен.

Так и поступим. Для главной формы тестового приложения создадим обработчик события OnCreate.

В появившейся заготовке обработчика кода объявим локальную переменную того же типа, что и разработанный класс.

Собственно в обработчике события теперь можно создать экземпляр компонента, вызвав конструктор класса.

Рис. 2.5. Использование подсказок в редакторе кода

После ввода имени класса нужно нажать <.> и ввести название конструктора Create. Конструктор принимает единственный параметр - ссылку на компонент-хозяин, который должен будет разрушить созданный экземпляр в случае необходимости. Чаще всего за это в ответе форма приложения, поэтому можно передать параметр по имени Self.

Другим важным свойством является Parent – компонент, который в ответе за отображение на экране. Его тоже можно установить в Self.

procedure TForm1.FormCreate(Sender: TObject);
var
TestZIP1:TsyPostZip;
begin
TestZIP1:=TsyPostZip.Create(Self);
TestZIP1.Parent:=Self;
end;

Теперь можно запустить тестовое приложение. Если все сделано правильно, то вы увидите пустую форму. Точнее будет сказать, что наш новый компонент присутствует на форме, но с нулевыми размерами и при этом с неопределенным методом отрисовки. Поэтому он никак себя не проявляет.

Для того чтобы каждый экземпляр нашего класса имел уже заданные размеры по умолчанию необходимо переопределить конструктор класса.

Для добавления в класс новой функциональности нужно переопределить некоторые из его методов. Установка размеров осуществляется в конструкторе, поэтому его и нужно переопределить.

Для переопределения конструктора откроем модуль, в котором определен наш класс.

В интерфейсной части класса поставим курсор в секции public и вызовем подсказку (<Ctrl>+<Пробел>). Отфильтруем ее, начав набирать первые буквы имени конструктора Create – “cr”.

В появившемся списке можно выбрать переопределение конструктора. При этом в интерфейсной части появиться следующая строка:

    constructor Create(AOwner: TComponent); override;

[Pascal Error] SyPOST.pas(14): E2065 Unsatisfied forward or external declaration: 'TsyPostZip.Create'

Это означает, что конструктор объявлен, но не реализован . Так реализуем же его. Для этого в реализационном разделе (implementation) нужно написать следующую конструкцию:

constructor TsyPostZip.Create(AOwner: TComponent);
begin
  inherited;

end;

Теперь в конструкторе можно установить необходимые размеры компонента по умолчанию, а для того, чтобы компонент как-то проявил себя на форме – установить курсор в отличное от умолчания значение.

constructor TsyPostZip.Create(AOwner: TComponent);
begin
  inherited;
  Width:=300;
  Height:=50;
  Cursor:=crHandPoint;
end;

Откомпилируйте и запустите тестовый проект, наведите курсор мыши на область, которую занимает компонент (в примере – 300 пикселей в ширину и 50 – в высоту) и убедитесь, что курсор принял форму «руки».

Для того, чтобы реализовать внешний вид компонента, необходимо переопределить метод Paint.

Для этого в модуле компонента в секции protected объявления класса нужно записать объявление метода:

    procedure Paint; override;

Ключевое слово override (переопределить) означает, что новая реализация метода становится актуальной.

Для начала нужно убедится, что все сделано верно. Для этого в реализации Paint нужно записать простой оператор отрисовки, не забыв первой строкой вызвать унаследованный метод Paint.

procedure TsyPostZip.Paint;
begin
  inherited;
  Canvas.Rectangle(ClientRect);
end; 

Рис. 2.6. В компоненте реализован метод Paint